OpenEdv-开源电子网

 找回密码
 立即注册

扫一扫,访问微社区

正点原子新作:阿波罗STM32F767&F429&探索者STM32F4开发板&赶快来下载资料哦。

查看: 1877|回复: 0

勇敢的芯伴你玩转Altera FPGA连载59:按键消抖与LED开关实例

[复制链接]

  离线 

365

主题

372

帖子

0

精华

金牌会员

Rank: 6Rank: 6

积分
1609
金钱
1609
注册时间
2014-7-19
在线时间
39 小时
发表于 2018-4-3 20:21:40 | 显示全部楼层 |阅读模式
正点原子公众号
勇敢的芯伴你玩转Altera FPGA连载59:按键消抖与LED开关实例
特权同学,版权所有
配套例程和更多资料下载链接:
http://pan.baidu.com/s/1i5LMUUD
1.jpg
         除了前面所论及的按键消抖处理,该实验还需要用到LED指示灯进行按键状态的指示。该实验要实现一个独立按键控制一个发光二极管亮暗状态翻转。上电初始,发光二极管不亮,当某一个按键被按下后(即键值为0),发光二极管被点亮,当按键再次被按下时,发光二极管则又灭了,按键控制发光二级管如此反复的进行亮暗变化。
         本实例代码如下。
module cy4(
            input ext_clk_25m, //外部输入25MHz时钟信号
            input ext_rst_n,   //外部输入复位信号,低电平有效
            input[3:0] key_v,//4个独立按键输入,未按下为高电平,按下后为低电平
            output reg[7:0] led    //8个LED指示灯接口   
            );
//-------------------------------------
//按键抖动判断逻辑
wire key;   //所有按键值相与的结果,用于按键触发判断
reg[3:0] keyr;  //按键值key的缓存寄存器
assign key = key_v[0] & key_v[1] & key_v[2] & key_v[3];
always @(posedge ext_clk_25m or negedge ext_rst_n)
    if (!ext_rst_n) keyr <=4'b1111;
    else keyr <= {keyr[2:0],key};
wire key_neg = ~keyr[2] & keyr[3]; //有按键被按下  
wire key_pos = keyr[2] & ~keyr[3]; //有按键被释放
//-------------------------------------
//定时计数逻辑,用于对按键的消抖判断
reg[19:0]  cnt;
    //按键消抖定时计数器
always @ (posedge ext_clk_25m or negedge ext_rst_n)
   if (!ext_rst_n) cnt <= 20'd0;   
    else if(key_pos || key_neg) cnt<= 20'd0;
    else if(cnt < 20'd999_999) cnt<= cnt + 1'b1;
    else cnt <= 20'd0;
  
reg[3:0] key_value[1:0];
    //定时采集按键值
always @(posedge ext_clk_25m or negedge ext_rst_n)
    if (!ext_rst_n) begin
        key_value[0] <= 4'b1111;
        key_value[1] <= 4'b1111;
    end
    else begin
        key_value[1] <=key_value[0];      
        if(cnt == 20'd999_999)key_value[0] <= key_v;  //定时键值采集
        else ;  
    end
wire[3:0] key_press = key_value[1] & ~key_value[0];       //消抖后按键值变化标志位
//-------------------------------------
//LED切换控制
always @ (posedge ext_clk_25m or negedge ext_rst_n)
    if (!ext_rst_n) led <= 8'hff;
    else if(key_press[0]) led[0]<= ~led[0];
    else if(key_press[1]) led[1] <=~led[1];
    else if(key_press[2]) led[2] <=~led[2];
    else if(key_press[3]) led[3] <=~led[3];
    else ;
  
endmodule
         这段代码的前提是,所有4个独立按键,在任意一个按键被按下和释放期间,不会有其它按键也被按下或释放。在通常的应用中,一定也是符合这个假设的场景。
         我们处理消抖的逻辑是这样的:首先将所有按键输入信号做“逻辑与”操作,得到信号key。信号key的值锁存4拍分别存储到寄存器keyr[0]、keyr[1]、keyr[2]和keyr[3]中(此时的采样频率和基准时钟一致,为25MHz),通过keyr[2]和keyr[3]这两个寄存器获得key信号的上升沿标志位key_pos和下降沿标志位key_neg。key_pos和key_neg的获得过程分别如图8.13和图8.14所示,这是很典型的“脉冲边沿检测法”,后续很多代码中我们都会用到这个逻辑。
2.jpg
图8.13 上升沿脉冲检测波形
3.jpg
图8.14 下降沿脉冲检测波形
计数器cnt在key_pos和key_neg有效拉高时,都会清零重新开始计数,计数器cnt的最大计数值为40ms,若在某个固定时间内按键有抖动(这个抖动通常不会大于40ms,这是经验值),那么这段时间内计数器cnt会频繁的清0,cnt的计数值就不会计数到最大值。一旦cnt计数到最大值,我们就会对当前所有的按键值做一次锁存,锁存到4位寄存器key_value[0]中(即这个锁存操作的采样率是40ms为周期的,若按键的抖动小于40ms,那么采样的按键值是不会变化的,那么就达到了消除抖动的目的)。随后,以系统时钟节拍下,key_value[1]会锁存key_value[0]的值。当按键按下操作,产生按键值的下降沿变化,那么key_press就会获得一个时钟周期高脉冲的键值指示信号,通过这个键值指示信号,我们就可以对LED的翻转做相应处理。

回复

使用道具 举报

您需要登录后才可以回帖 登录 | 立即注册

本版积分规则




QQ|联系我们|手机版|官方淘宝店|新浪微博|微信公众平台|OpenEdv-开源电子网 ( 粤ICP备12000418号-1 )

GMT+8, 2018-6-22 07:42

Powered by OpenEdv-开源电子网

© 2001-2030 OpenEdv-开源电子网

快速回复 返回顶部 返回列表
/* */